#!/usr/bin/perl -s
#
# mkpeople - rebuild the Web People Directory for IU Computer Science
# Steve Kinzler, kinzler@cs.indiana.edu, Sep 94/Jul 95/Nov 95/May 97
#
# comments added for sanity -- schisham 19971007
# converted to new web structure  -- robh   Oct 2001
# added exceptgroups to limit the display (and web harvesting of email addrs) - robh  May 2004
#
# $Id: mkpeople,v 1.25 2007/05/03 16:23:18 root Exp root $

umask 002;

# head/tail files
$headfile="/l/www/People/headonly.html";
$tailfile="/l/www/People/tailonly.html";

# base url
$base="/People/auto/";

# location of mkpeople
$cwd     = '/l/www/People/auto';

# root of WWW tree
$root    = '../..';

# usernames to exclude
$except  = '/usr/local/lib/userlist/nonusers';
@except  = ('^[A-Z]');

# groups to exclude
@exceptgroups = (	'other',
			'classes',
			'csother',
			'cssystem',
			'guests',
			'projects',
			'students',
			'xfaculty',
			'alumni',
			'xstaff');

# file that, if existing in the homedir of a user, excludes them from the listing
$excludefile = ".web.exclude";

# machines serving as password hosts
@pwhost  = ('moose', 'whale', 'silo');
# where to find the password file on the passwd hosts
%pwfile  = ('whale',     '/nfs/whale/etc/passwd',
	    'moose',     '/nfs/moose/etc/passwd',
	    'silo',      '/nfs/silo/etc/passwd');
$maxname = 50;
# lower UID limit
$minuid  = 100;
$primary = 'PRIMARY';
# default group if none match
$dfltgrp = 'other';

# shells for skipped accounts
@deactiv = ('deactivated');

$foto    = "$root/foto";

# hyplan link for personal WWW pages
$hyplan  = "$root/hyplan";	# via filesystem
$hyplanroot = "/hyplan";	# via web

# resume forwarding filename
$resufwd = 'resume.forward';

# filenames for actual resume
@resume  = ('resume.html', 'resume.txt');

# Address and fax override filenames.  If these exist in the
# users moose home directory, use them instead of the defaults
# for the mailing address and fax number.
$addressfile=".web.address";
$faxfile=".web.fax";
$emailfile=".web.email";

# no longer used
#$facls   = "$root/dept/faclist";

# part of page title
$title   = 'IU Computer Science';
$bgcolor = '#FFFFFF';
$montage = 'bin/usermontage';
$maxcols = 10;
$swapgif = 1;	# do we need to byte-order swap for correct GIF sizes?
$montpad = 0;	# does $montage pad out to $maxcols columns?
$type2c  = 's';

$domain  = 'cs.indiana.edu';
$areacod = '812';
$prefix  = '85';
$deptadd = 'Lindley Hall 215; Bloomington, IN 47405 USA';
@deptadd = ('admin', 'faculty', 'research', 'staff');
$deptfax = "$areacod-${prefix}5-4829";
@deptfax = ('admin', 'faculty', 'research', 'staff');

# student groups and file locations
%subgrp  = ('grads',    'students /usr/local/lib/userlist/phdgrads /usr/local/lib/userlist/msgrads',
	    'majors',   'students /usr/local/lib/userlist/csmajors');
%supgrp  = ('supstaff', 'research    staff       admin     wkstudy');
# Group order ?
@gorder  = ('faculty',  'supstaff',
	    'grads',    'majors',   'students', 'alumni', 'other');
# Group long names in assoc array
%gname   = ('admin',    'Admin Staff',   'alumni',   'Alumni',
	    'faculty',  'Faculty',       'grads',    'Graduate Student',
	    'other',    'Guest',         'research', 'Research Staff',
	    'staff',    'Systems Staff', 'students', 'Other Student',
	    'supstaff', 'Staff',         'majors',   'Undergraduate Major',
	    'wkstudy',  'Work-study');
# Group long names plural
%gname2  = ('admin',    'Admin Staff',   'alumni',   'Alumni',
	    'faculty',  'Faculty',       'grads',    'Graduate Students',
	    'other',    'Guests',        'research', 'Research Staff',
	    'staff',    'Systems Staff', 'students', 'Other Students',
	    'supstaff', 'Staff',         'majors',   'Undergraduate Majors',
            'wkstudy',  'Work-studies');


chdir $cwd || die "$0: cannot chdir $cwd ($!)\n";

## Collect User Data ##########################################################

while (@grent = getgrent) {
	$primary{$grent[2] + 0} = $grent[0]
		if $grent[3] =~ /(^|[ ,])$primary([ ,]|$)/;
}
endgrent;

# build exceptions array
open(EXCEPT, $except) || die "$0: cannot open $cwd/$except ($!)\n";
while (<EXCEPT>) {
	chop;
	s/^\s*//; s/\s.*//;
	next if /^$|^#/;
	$except{$_} = 1;
}
close EXCEPT;

# parse the password hosts's passwd files
# grab everyone, but exceptions, deactivated, lowUIDs
foreach $pwhost (@pwhost) {
        # open the passwd file on hosts
	($pwfile = $pwfile{$pwhost}) ||
		die "$0: undefined password file for $pwhost\n";
	open(PASSWD, $pwfile) || die "$0: cannot open $pwfile ($!)\n";
	while (<PASSWD>) {
	        # get passwd entries
		@pwent = split(/:/);
		# username is first entry
		$user  = $pwent[0];
		# skip if no username or UID is below $minuid
		# or this is an exception person or this person's
		# account has been disabled
		next if ! $user || $pwent[2] < $minuid ||
			$except{$user} || grep($user =~ /$_/, @except) ||
			grep($pwent[6] =~ /$_/, @deactiv);

		# Skip if the user has a $excludefile in any CS homedir
		next if (  -e "/nfs/moose/u/$user/$excludefile"
			|| -e "/nfs/whale/u/$user/$excludefile"
			|| -e "/nfs/silo/u/$user/$excludefile" );

		# grab userinfo from host only once
		unless ($host{$user}) {
			$host{$user}   = $pwhost;
			$group{$user}  = $primary{$pwent[3] + 0} || $dfltgrp;
			# grab the GECOS info and canonicalize it
			split(/,/, $pwent[4], 4);
			$name{$user}   = &canon($_[0], 'name');
			$office{$user} = &canon($_[1]);
			$wphone{$user} = &canon($_[2], 'phone');
			$hphone{$user} = &canon($_[3], 'phone');
			$members{$group{$user}} .=
				(($members{$group{$user}}) ? ':' : '') . $user;
		}
	}
	close PASSWD;
}


foreach $subgrp (keys %subgrp) {
	($group, @files) = split(/\s+/, $subgrp{$subgrp});
	foreach (@files) {
		open(FILE, $_) || die "$0: cannot open $_ ($!)\n";
		grep(s/^\s*([^\s@]+).*\n/$1/ && ($subusers{$_} = 1) && 0,
		     <FILE>);
		close FILE;
	}
	foreach (split(/:/, $members{$group})) {
		if ($subusers{$_}) {
			$group{$_} = $subgrp;
			push(@submembers, $_);
		} else {
			push(@members,    $_);
		}
	}
	$members{$subgrp} = join(':', @submembers);
	$members{$group}  = join(':', @members);
	%subusers = @submembers = @members = ();
}

opendir(DIR, $foto) || die "$0: cannot opendir $foto ($!)\n";
foreach (readdir DIR) {
	next if /^\./;
	# look for a foto in the foto dir of that person
	($user = $_) =~ s/\.[^.]*$//;
	$foto{$user} =  $_;
}
closedir DIR;

# look for username/index.[s]html and username.html files in hyplan directory
opendir(HYPLAN, $hyplan) || die "$0: cannot opendir $hyplan ($!)\n";
foreach $f (readdir HYPLAN) {

	# If we have an index.[s]html in a hyplan directory,
	# we use the ~user form.
	if (-f "$hyplan/$f/index.html" || -f "$hyplan/$f/index.shtml" ) {
	    $hyplan{$f} = "/~$f";
	}

	# Otherwise, we look for a .html file
	else {

	    # We only care about .html files at this point
	    next unless ($f =~ /^(\w+)\.html$/);

	    # Get the user and initialize href
	    ($user, $href) = ($1, '');

	    # If we already have something for this user, skip it
	    next if $hyplan{$user};

	    # If the .html file is a link, use the hyplan/user.html form
	    if (-l "$hyplan/$f") {
		$href = $f;
	    }

	    # If the .html file is a real file, see if it is a hyplan forward
	    elsif (-f _) {
		warn("$0: cannot open $hyplan/$f ($!)\n"), next
			unless open(HYFWD, "$hyplan/$f");
		($href = (grep(s/.*href="?//i, <HYFWD>))[0]) =~ s/"?[\s>].*//;
		close HYFWD;
		$href  =~ s/[\s"<>].*//;
	    }

	    # build the url
	    $hyplan{$user} = (($href =~ m,^(\w+:|/),) ? '' : "$hyplanroot/") . $href
		if $href;
	}

}
#rewinddir HYPLAN || die "$0: cannot rewinddir $hyplan ($!)\n";
close HYPLAN;

# build the /hyplan/username/ links
opendir(HYPLAN, $hyplan) || die "$0: cannot opendir $hyplan ($!)\n";
foreach $user (readdir HYPLAN) {
	next unless $user =~ /^\w+$/ && -l "$hyplan/$user";
        # look for a resume forwarder
	if (-s "$hyplan/$user/$resufwd" &&
	    open(RESFWD, "$hyplan/$user/$resufwd")) {
		$href = (grep(s/^\s*(\S+).*(\n|$)/$1/, <RESFWD>))[0];
		close RESFWD;
		$href =~ s/[\s"<>].*//;
		$resume{$user} = (($href =~ m,^(\w+:|/),) ? ''
					: "$hyplan/$user/") . $href if $href;
        # look for local resume files
	} elsif ($resume = (grep(-s "$hyplan/$user/$_", @resume))[0]) {
		$resume{$user} = "$hyplanroot/$user/$resume";
	}
	# skip if we already have this person from another host
        # host order is important
	next if $hyplan{$user};
	$hyplan{$user} = (-e "$hyplan/$user/index.html") ?
				"$hyplan/$user/index.html" : "$hyplan/$user/";
}
close HYPLAN;

#opendir(DIR, $facls) || die "$0: cannot opendir $facls ($!)\n";
#foreach (readdir DIR) {
#	next unless /^(\w+)\.html$/;
#	$facls{$1} = $facls . '/' . $_;
#}
#closedir DIR;

## Delete Extra Pages and Prepare Page Segments ###############################

$proot   = ($root   =~ /^\//) ? '' : '../';
$pfoto   = ($foto   =~ /^\//) ? '' : '../';
$phyplan = ($hyplan =~ /^\//) ? '' : '../';
#$pfacls  = ($facls  =~ /^\//) ? '' : '../';

# scroll through the 1 char length dir names
foreach $dir (<?>) {
	opendir(DIR, $dir) || die "$0: cannot opendir $cwd/$dir ($!)\n";
	foreach (readdir DIR) {
		next if /^\.\.?$/;
		unlink "$dir/$_" || die "$0: cannot unlink $cwd/$dir/$_ ($!)\n"
			unless ($user = $_) =~ s/\.html$// && $host{$user};
	}
	closedir DIR;
	rmdir $dir;
}

%tmp = %members;
foreach $group (@gorder) {
	@supgrp = grep(delete $tmp{$_}, split(/\s+/, $supgrp{$group}));

	# We exclude certain groups
	next if grep $group =~ /^$_$/, @exceptgroups;

	push(@groups, $group) if delete $tmp{$group} || @supgrp;
}
foreach $group (sort keys %tmp) {

	# We exclude certain groups
	next if grep $group =~ /^$_$/, @exceptgroups;

	push(@groups, $group) if delete $tmp{$group};
}

foreach $file (<*.html>) {
	next if $file eq 'index.html';
	($group = $file) =~ s/T?\.[^.]*$//;
	unlink $file || die "$0: cannot unlink $cwd/$file ($!)\n"
		unless grep($_ eq $group, @groups);
}
foreach $file (<*.gif>) {
	($group = $file) =~ s/\.[^.]*$//;
	unlink $file || die "$0: cannot unlink $cwd/$file ($!)\n"
		unless $members{$group};
}

# build arrays from trailing data in script
while (<DATA>) { last if /__DONTEDIT__/; push(@head,	 $_); }
while (<DATA>) { last if /__TITLE__/;	 push(@dontedit, $_); }
while (<DATA>) { last if /__INTRO__/;	 push(@title,	 $_); }
while (<DATA>) { last if /__SEARCH__/;	 push(@intro,	 $_); }
while (<DATA>) { last if /__FOOTNOTE__/; push(@search,	 $_); }
while (<DATA>) { last if /__TAIL__/;	 push(@footnote, $_); }
while (<DATA>) {			 push(@tail,	 $_); }

# add a bit to the menu
push(@menu, "\n", <<'EOF');
<center><table border=4 bgcolor="#CCCCCC">
<tr><td align=center>
EOF
push(@menu, "<strong>Text Listings</strong><br>\n[ ");
foreach $group (@groups) {
	$gname2 = $gname2{$group} || $group;
	push(@menu, ($n++) ? '| ' : '',
		    "<a href=\"${group}T.html\">$gname2</a>\n");
}
$n = 0;
push(@menu, "]<br>\n");
push(@menu, "</td></tr><tr><td align=center>\n");
push(@menu, "<strong>Icon Listings</strong><br>\n[ ");
foreach $group (@groups) {
	$gname2 = $gname2{$group} || $group;
	push(@menu, ($n++) ? '| ' : '',
		    "<a href=\"$group.html\">$gname2</a>\n");
}
push(@menu, "]\n");
push(@menu, "</td></tr>\n</table></center>\n");

## Write Main Index ###########################################################

open(INDEX, '> index.html') || die "$0: cannot open $cwd/index.html ($!)\n";
printhead(INDEX);
print INDEX @head, @dontedit, @title, "<h2>Main Index</h2>\n",
	    @intro, @search, @menu, @tail;
printtail(INDEX);
close INDEX;

exit if $exitindex;

## Write Text Listings ########################################################

@tmp       = @groups;
$prevgroup = '';
while ($group = shift @tmp) {
	$nextgroup = $tmp[0];
	$gname2    = $gname2{$group} || $group;

	open(GROUP, "> ${group}T.html") ||
		die "$0: cannot open $cwd/${group}T.html ($!)\n";
	print GROUP @dontedit;
	printhead(GROUP);

	print GROUP @title, "<h2>Text Listing - $gname2</h2>\n", @intro;

	$prevhtml = ($prevgroup)
		? "<a href=\"${prevgroup}T.html\">Previous Text Listing</a>"
		: 'Previous Text Listing';
	$nexthtml = ($nextgroup)
		? "<a href=\"${nextgroup}T.html\">Next Text Listing</a>"
		: 'Next Text Listing';
	print GROUP "\n", <<EOF, @search;
<center><p>
[ <a href="index.html">Main Index</a>
| <a href="$group.html">Icon Listing</a>
]<br>
$prevhtml &lt;--&gt;
$nexthtml
</p></center>
EOF

	@supgrp = &supgrps($group);
	foreach $supgrp (@supgrp) {
		$gname2  = $gname2{$supgrp} || $supgrp;
		$supgrp2 = ($supgrp eq $group) ? "${supgrp}2" : $supgrp;
		print GROUP "\n<h3><a name=\"$supgrp2\">$gname2</a></h3>\n"
			if $#supgrp > 0;

		@members = sort split(/:/, $members{$supgrp});
		push(@users, @members);
		$supergroup{$supgrp} = $group;

		print GROUP "\n<blockquote>\n";
		foreach $user (@members) {
			print GROUP &userline($user), "<br>\n";
		}
		print GROUP "</blockquote>\n";
	}

	print GROUP @footnote, @tail;
	printtail(GROUP);
	close GROUP;

	$prevgroup = $group;
}

exit if $exittext;

## Write Icon Listings ########################################################

$prevgroup = '';
while ($group = shift @groups) {
	$nextgroup = $groups[0];
	$gname2    = $gname2{$group} || $group;

	open(GROUP, "> $group.html") ||
		die "$0: cannot open $cwd/$group.html ($!)\n";
	print GROUP @dontedit;
	printhead(GROUP);

	print GROUP @title, "<h2>Icon Listing - $gname2</h2>\n", @intro;

	$prevhtml = ($prevgroup)
		? "<a href=\"$prevgroup.html\">Previous Icon Listing</a>"
		: 'Previous Icon Listing';
	$nexthtml = ($nextgroup)
		? "<a href=\"$nextgroup.html\">Next Icon Listing</a>"
		: 'Next Icon Listing';
	print GROUP "\n", <<EOF;
<center><p>
[ <a href="index.html">Main Index</a>
| <a href="${group}T.html">Text Listing</a>
]<br>
$prevhtml &lt;--&gt;
$nexthtml
</p></center>
EOF

	@supgrp = &supgrps($group);
	foreach (@supgrp) {
		&groupmontage($_);
	}

	print GROUP @tail;
	printtail(GROUP);
	close GROUP;

	$prevgroup = $group;
}

sub groupmontage {
	local($group) = @_;

	@members = sort split(/:/, $members{$group});

	warn("$0: cannot run $montage ($!)\n"), return
		unless open(MONTAGE, "| $montage $maxcols $group.gif");
	print MONTAGE join("\n", @members), "\n";
	close MONTAGE;
	return if $? >> 8;

	warn("$0: cannot open $cwd/$group.gif ($!)\n"), return
		unless open(MONTAGE, "< $group.gif");

	# grab the magic info to determine if file is a GIF
	read(MONTAGE, $magic, 10);
	@magic = (unpack('c10', $magic))[6 .. 9];;
	close MONTAGE;
	@magic = @magic[1, 0, 3, 2] if $swapgif;

	# this is pretty cool stuph
	# read the header to determine width and height settings
	# Steve never ceases to amaze me --schisham
	$width   = unpack($type2c, pack('cc', @magic[0, 1]));
	$height  = unpack($type2c, pack('cc', @magic[2, 3]));
	$columns = (! $montpad && $#members + 1 < $maxcols) ?
		   $#members + 1 : $maxcols;
	$rows    = int(($#members + 1) / $columns + .9999);
	$twidth  = int($width  / $columns) - 2;
	$theight = int($height / $rows)    - 2;

	$gname2  = $gname2{$group} || $group;
	print GROUP "\n<h3><a name=\"$group\">$gname2</a></h3>\n"
		if $#supgrp > 0;

	$size = ($#members == 0) ? "1 multiple"  :
		($#members <  5) ? $#members + 1 : 5;

# a little javascript action
	print GROUP "\n", <<EOF;
<center><form><select size=$size
onChange="o=this.options[this.selectedIndex]; if (o) window.location = o.value">
EOF
	foreach $user (@members) {
		print GROUP '<option value="', substr($user, 0, 1),
			"/$user.html\">$user - $name{$user}\n";
	}
	print GROUP "</select></form></center>\n";

	print GROUP "\n<map name=\"map_$group\">\n";
	$row = $col = 0;
	foreach (@members) {
		$x = int($col * ($width  / $columns) + .9999);
		$y = int($row * ($height / $rows)    + .9999);
		print GROUP "<area shape=rect coords=\"$x,$y, ",
			      $x + $twidth, ',', $y + $theight,
			      '" href="', substr($_, 0, 1), "/$_.html\">\n";
		$col = 0, $row++ if ++$col >= $columns;
	}
	print GROUP "<area shape=default href=\"${group}T.html\">\n",
		    "</map>\n\n", <<EOF;
<center><a href="${group}T.html">
<img src="$group.gif" alt="Text Listing" border=0 width=$width height=$height
 usemap="#map_$group"></a></center>
EOF
}

exit if $exiticon;

## Write User Pages ###########################################################

while ($user = shift @users) {
	$nextuser = $users[0];

	$name   = $name{$user}   || $user;
	$group  = $group{$user};
	$gname  = $gname{$group} || $group;

	$dir = substr($user, 0, 1);
	mkdir($dir, 0777 & (0777 ^ umask)) ||
		die "$0: cannot mkdir $cwd/$dir ($!)\n" unless -e $dir;
	open(FILE, "> $dir/$user.html") ||
		die "$0: cannot open $cwd/$dir/$user ($!)\n";

	print FILE @dontedit;
	printhead(FILE);
	print FILE "\n", <<EOF;
<center>
<em>Indiana University Computer Science Personnel Directory</em><br>
[ <a href="../index.html">Main Index</a>
| <a href="../$supergroup{$group}T.html">Text Listing</a>
| <a href="../$supergroup{$group}.html">Icon Listing</a>
]<br>
EOF
	print FILE &userseq($prevuser, $user, 'Previous Page'),
		   " &lt;--&gt;\n", &userseq($nextuser, $user, 'Next Page'),
		   "\n</center>\n";

	print FILE "\n<hr>\n";

	print FILE "\n<h1>\n";
	print FILE "<img src=\"$pfoto$foto/$foto{$user}\" alt=\"\" align=right>\n"
		if $foto{$user};
	print FILE "$name\n</h1>\n";

	print FILE "\n<ul>\n";
	print FILE '<li><a href="',
		   # ($hyplan{$user} =~ m,^(\w+:|/),) ? '' : $phyplan,
		   "$hyplan{$user}\">\n",
		   "My personal Web page (<em>hyplan</em>)</a>.\n"
		if $hyplan{$user};
	print FILE "<li><a href=\"",
                   # $resume{$user} =~ /^\.\.\// ? $phyplan : '',
		   "$resume{$user}\">\n",
		   "My r&eacute;sum&eacute; (<em>resume</em>)</a>.\n"
		if $resume{$user};
#	print FILE <<EOF;
#<li><a href="http://www.cs.indiana.edu/finger/$host{$user}.$domain/$user/w">
#Finger me</a> for more information or to see if I'm logged on.
#EOF
	# These are hopelessly out of date
	#print FILE "<li><a href=\"$pfacls$facls{$user}\">\n",
	#	   "My departmental report narrative</a>.\n"
	#	if $facls{$user};
	print FILE "</ul>\n";

	@out = ("<BR><strong>Position:</strong> $gname");
	push(@out, "<strong>Office:</strong> $office{$user}")
		if $office{$user};

	# Print the address if in one of the deptadd groups, looking
	# for an addressfile override.
	if (grep($group eq $_, @deptadd)) {
	  if ( -r "/nfs/moose/u/$user/$addressfile") {
	    $addrtmp=`cat /nfs/moose/u/$user/$addressfile`;
	    push(@out, "<strong>Address:</strong> $addrtmp");
	  }
	  else {
	    push(@out, "<strong>Address:</strong> $deptadd");
	  }
	}

	push(@out, "<strong>Office phone:</strong> $wphone{$user}")
		if $wphone{$user};

	# Print the fax number if in one of the deptadd groups, looking
	# for a faxfile override.
	if (grep($group eq $_, @deptadd)) {
	  if ( -r "/nfs/moose/u/$user/$faxfile") {
	    $faxtmp=`cat /nfs/moose/u/$user/$faxfile`;
	    push(@out, "<strong>Fax phone:</strong> $faxtmp");
	  }
	  else {
	    push(@out, "<strong>Fax phone:</strong> $deptfax");
	  }
	}

	push(@out, "<strong>Home phone:</strong> $hphone{$user}")
		if $hphone{$user};

	# Print the email address, looking for a emailfile override.
	if ( -r "/nfs/moose/u/$user/$emailfile") {
		chomp($emailtmp=`cat /nfs/moose/u/$user/$emailfile`);
	}
	elsif ( -r "/nfs/whale/u/$user/$emailfile") {
		chomp($emailtmp=`cat /nfs/whale/u/$user/$emailfile`);
	}
	elsif ( -r "/nfs/silo/u/$user/$emailfile") {
		chomp($emailtmp=`cat /nfs/silo/u/$user/$emailfile`);
	}
	else {
		$emailtmp="$user\@$domain";
	}
	push(@out, "<strong>E-mail:</strong>\n" . &maillink($emailtmp));
	print FILE "\n", join("<br>\n", @out), "\n";

	print FILE "<br><br><br><blockquote><i><small>See the <a href=\"http://www.cs.indiana.edu/Facilities/FAQ/WWW/people.html\">";
	print FILE "associated FAQ Entry</a> if you want to change the contents of this page</small></i></blockquote>\n";
	printtail(FILE);

	close FILE;

	$prevuser = $user;
}

exit 0;

## General Subroutines ########################################################

# canonicalize GECOS info from passwd file
sub canon {
	local($_) = shift;

	s/\s+/ /g; s/^ //; s/ $//;
	s/[^ -~]//g;
	# [<>&] go bye-bye
	s/&/&amp;/g; s/</&lt;/g; s/>/&gt;/g;

	foreach $key (@_) {
		if ($key eq 'name') {
			$_ = substr($_, 0, $maxname) if length > $maxname;
		}
		# the following looks like sendmail rules ;)
		# parse a phone number
		if ($key eq 'phone') {
			s/^\( ?(\d{3}) ?\) ?-* ?/$1-/;
			s/^(\d{3})[- .\/]?(\d{3})[- .\/]?(\d{4})$/$1-$2-$3/;
			s/^(\d{3})[- .\/]?(\d{4})$/$areacod-$1-$2/;
			s/^(\d)[- .\/]?(\d{4})$/$areacod-$prefix$1-$2/;
		}
	}

	return $_;
}

sub supgrps {
	local($group) = @_;
	@_ = ($members{$group}) ? ($group) : ();
	push(@_, grep($_ =~ /\S/ && $members{$_},
		      split(/\s+/, $supgrp{$group}))) if $supgrp{$group};
	return @_;
}

sub userline {
	local($user) = @_;
	return	'<tt><a href="' . $base . substr($user, 0, 1) .
		"/$user.html\">$user</a> " .
		'...' . '.' x ((8 - length($user)) % 8) .
		(($hyplan{$user}) ? " <a href=\"$hyplan{$user}\">hyplan</a>"
				  : '.......') .
		(($hyplan{$user} &&   $resume{$user}) ? ',' :
		 ($hyplan{$user} && ! $resume{$user}) ? ' ' : '.') .
		(($resume{$user})
		    ? " <a href=\"$resume{$user}\">r&eacute;sum&eacute;</a> "
		    : '........') . "...</tt> " .
		$name{$user} . (($foto{$user}) ? ' *' : '');
}

sub userseq {
	local($ref, $rel, $txt) = @_;
	local($dir);
	return $txt unless $ref;
	return '<a href="' .
	       ((($dir = substr($ref, 0, 1)) eq substr($rel, 0, 1))
		? '' : "../$dir/") . "$ref.html\">$txt</a>";
}

# Printer the html header
sub printhead {
    local($f) = @_;
    if (open(HEADF, "<$headfile")) {
	while(<HEADF>) {
		print $f $_;
	}
	close(HEADF);
    }
    else {
        print $f "<H1>HEADER NOT AVAILABLE</H1>\n"
    }
}

# Printer the html footer
sub printtail {
    local($f) = @_;
    if (open(TAILF, "<$tailfile")) {
	while(<TAILF>) {
		print $f $_;
	}
	close(TAILF);
    }
    else {
        print $f "<H1>FOOTER NOT AVAILABLE</H1>\n"
    }
}

sub maillink {

  my ($addr) = @_;

  if ($addr =~ /^(.*)\@cs.indiana.edu$/) {
    return("<a href=\"/cgi-bin/tomail.cgi?name=$1\">$1</a>");
  }
  elsif ($addr =~ /^(.*)\@(.*)$/) {
    return("<a href=\"/cgi-bin/tomail.cgi?name=$1&domain=$2\">$1</a>");
  }
  elsif ($addr =~ /unlisted/i ) {
    return("Unlisted");
  }
  else {
    return("Invalid User-Supplied Email Address");
  }

}


## Page Segments ##############################################################

__END__

__DONTEDIT__

<!-- DO NOT EDIT.  THIS FILE IS AUTOMATICALLY GENERATED -->
__TITLE__

<h1>
<img src="/picons/db/domains/edu/indiana/cs/unknown/face.gif" alt=""
 align=left border=0 width=48 height=48>
Personnel Directory
</h1>
__INTRO__

<p>The information in this directory is garnered nightly from accounts
on the CS systems.  Persons listed
in this directory can change their full name, office, and office and
home phone using the
<a href="/Facilities/FAQ/Accounts/changepassword.html">account management system</a>.
You can also <a href="../hyplan-info.html">create
a personal web page (a <em>hyplan</em>) and r&eacute;sum&eacute;
(<em>resume</em>)</a>, and <a href="/Facilities/FAQ/General/photos.html">create and submit
a departmental photo</a>.  The icons in this directory are from the
<a href="/picons/ftp/index.html">Picons Archive</a>, and may be rendered
poorly by some browsers due to dithering.</p>
<p><blockquote><i><b>PLEASE NOTE:</b>  This directory includes only people with current accounts on
the CS systems.  This listing does not include
people who do not have CS accounts so some of the lists may not include
everyone in the specified group.</i></blockquote></p>

__SEARCH__

<p><center>
<form action="http://www.cs.indiana.edu/cgi-bin/greppeople.cgi" method=GET>
<input type=text name=isindex maxlength=127>
<input type=submit value="Search">
</form>
</center>
__FOOTNOTE__

<p><hr>
* An image of this person is available.
__TAIL__

<p>This directory is generated with
<a href="bin/mkpeople"><code>mkpeople</code></a>,
<a href="bin/greppeople.cgi"><code>greppeople</code></a> and
<a href="bin/usermontage"><code>usermontage</code></a>.</p>

<address>
written by
&lt;<a href="../hyplan/kinzler.html">kinzler@cs.indiana.edu</a>&gt;
</address>