|			Daisy code for OFF and PIV

| Vertical-bar is the comment character.  Carat is 'quote'.
| Infix shriek is 'cons'.  Infix colon is application.  Backslash is 'lambda'.
| A decorated matrix has the template,		[[max ibit jbit] ! undecrtdmtx]
| An undecorated matrix has the template,			[NW NE SW SE]

IDENT = \a.a			SWAP= \[a b].<b a>

OFF = \[decorMtx elimrowcol pcolrow index]. if:<
	any?: <\[p].VOID?:p *>:<pcolrow>  decorMtx	| Pivot row or col is 0.
	one?:index decorDIFFERENCE:<elimrowcol		|Indexed to pivot level.
				decorMtx decorPRODUCT:<elimrowcol ! pcolrow> >
	decorNORMALIZE:<elimrowcol
			    <OFF		OFF	OFF	OFF	>: <
    if:<Scalar?:decorMtx    <decorMtx		0	0	decorMtx>
								tail:decorMtx>
				    spread4:elimrowcol
				    <IDENT*>:SWAP:<IDENT*>:spread4:SWAP:pcolrow
			    <	div:<index 2>			*	>   > >>

spread4 = \[erow ecol]. let:[
    [			[eleft eright]				[etop ebot]   ]
    <if:<Scalar?:erow	<erow  erow  >
	  isAtm?:erow	<erow  erow  >
			    erow	> 
					if:<Scalar?:ecol	<ecol ecol>
					     isAtm?:ecol	<ecol ecol>
								   ecol     > >
    <<eleft etop>	<eright etop>	<eleft ebot>	<eright ebot>>]

PIVOT = \[decorMtx elimrowcol permutT]. if:<
	|returns
	|    [decorMtx [elimrow elimcol] permutT [pivotrow pivotcol][ipos jpos]]
			| permutT is a permutation matrix---normalized
			| elimrow and elimcol  are boolean vectors;
			|	[] => that row is eliminated
			| pivotrow and pivotcol  
			|	are vectors of numbers, respectively
			|     b/a  and  +c  entries
			|	except for pivot elt, which is  1/a  or -1/a
			| ipos and jpos are inverse-bit rel indices of pivot elt
	Scalar?:decorMtx	let:[ reciprocal  scalarRECIPROCAL:decorMtx
	    < reciprocal [[] []] 1 <scalarNEGATE:reciprocal reciprocal> [1 1]> ]
			|   Pivotrow entry is -1/a for pivot column construction
			|   Pivotcol entry is +1/a for pivot row construction
			|   No i,j coordinates here
			|	because logarithms are zero; base case.
	let:[  [permutT [[max ibit jbit] ! mtx]
			[pII pIII pIV stet incr] ]
	       <if:<isNUMERAL?:permutT <permutT 0 0 permutT> permutT>
		decorMtx
		<\[i ii iii iv].<ii i iv iii>	|pII	permute NE quad to NW
		 \[i ii iii iv].<iii iv i ii>	|pIII	permute SW quad to NW
		 \[i ii iii iv].<iv iii ii i>	|pIV	permute SE quad to NW
		 \n.add:<n n>			|stet	index builder
		 \n.inc:add:<n n>		|incr	index builder
	        >
	       >
	let:[			     [perMTX perPT perROW perCOL tweaki tweakj]
			|  These are all permutations for arguments &/or results
	  if:<		| Make all cases uniformly manipulate upper-left quad
		all?:<zero?:ibit zero?:jbit> <IDENT IDENT IDENT IDENT stet stet>
		zero?:ibit		     <pII   pIII  IDENT SWAP  stet incr>
		zero?:jbit		     <pIII  pII   SWAP  IDENT incr stet>
					     <pIV   pIV   SWAP  SWAP  incr incr>
	     >
	let:[[ [epivot [] [] [eright ebot]]	[permutHEAD!permutTAIL]	]
	     < perMTX:spread4:elimrowcol	perPT:permutT		>
	rec:[
	    [	[i [eleft etop] permutPIVOT [pleft ptop] [ipos jpos]]
		    [ii pright]  [iii pbot] iv]
		<PIVOT		ROW		COL		OFF	     >:<
		perMTX:mtx
		<epivot 	<eright etop>	<eleft ebot>	<eright ebot>>
		<permutHEAD	ptop		pleft		<pbot pright>>
		<[]		ipos		jpos		*	     > >
	let:[ [ elimrowcol pivotrowcol]
	      < < if:<all?:<nil?:eleft nil?:eright> [] perCOL:<eleft eright>>
		  if:<all?:<nil?:etop  nil?:ebot  > [] perROW:<etop  ebot  >> >
	 	<perCOL:<pleft pright>		perROW:<ptop pbot>	      >
	      >
	<decorNORMALIZE:<elimrowcol   perMTX:<i ii iii iv> >
	    elimrowcol
	    Normalize:perPT:<permutPIVOT ! permutTAIL>
	    pivotrowcol			<tweaki:ipos tweakj:jpos>	>
	]]]]  ]>