# .login - *csh login startup file
# Steve Kinzler, kinzler@cs.indiana.edu, Mar 98
# http://www.cs.indiana.edu/~kinzler/home.html#unixcfg

if ( $?COLUMNS && $?LINES ) then
	if ( $COLUMNS == 62 && $LINES == 41 ) setenv KINDLE shellinabox
endif

if ( ! $?SHELL && $?shell ) setenv SHELL "$shell"

if ( ! $?TERM ) setenv TERM unknown
if ( $TERM == dialup || $TERM == network ) set term = ansi
# not really equivalent, but this works well for ConnectBot's default term:
if ( $TERM == screen )			   set term = xterm16

if ( "$TERMCAP" !~ *:* && ( -x /usr/ucb/tset || -x /usr/bin/tset ) ) then
	tset -sIQ > /tmp/tset$$
	source /tmp/tset$$; rm -f /tmp/tset$$
endif

setenvls -c > /tmp/sls$$
source /tmp/sls$$; rm -f /tmp/sls$$

if ( ! $?REMOTEHOST ) then
	setenv REMOTEHOST `who am i | sed -n 's/.*(\([^) ]*\).*/\1/p; 1q'`
	if ( "$REMOTEHOST" == localhost ) setenv REMOTEHOST ''
	if ( "$REMOTEHOST" !~ *.edu && "$REMOTEHOST" !~ *.[0-9][0-9][0-9] && \
	     "$REMOTEHOST" !~ *.net && "$REMOTEHOST" !~ *.[0-9][0-9]      && \
	     "$REMOTEHOST" !~ *.com && "$REMOTEHOST" !~ *.[0-9] ) then
		setenv REMOTEHOST `echo "$REMOTEHOST" | sed 's/\..*//'`
	endif
endif

setenv KH `hosts ppp | sed 1q`

unsetenv LINUX
if	( $TERM == putty || $?KINDLE ) then
	setenv LINUX del
else if ( "$REMOTEHOST" =~ dkinzler* || "$REMOTEHOST" =~ pcp[0-9]* || \
	  "$REMOTEHOST" =~ alamo*    || "$REMOTEHOST" =~ swank*    || \
	  "$REMOTEHOST" =~ trendy*   || "$REMOTEHOST" =~ transit* ) then
	setenv LINUX bs
else if ( "$REMOTEHOST" =~ ?kinzler* || "$REMOTEHOST" == 141.211.15.29 || \
					"$REMOTEHOST" =~ *.comcast.net || \
	  $TERM == linux || $TERM == vt102 ) then
	setenv LINUX del
else if ( "$REMOTEHOST" != "" ) then
	if ( "`hosts -l "$REMOTEHOST"`" =~ *linux* ) setenv LINUX del
else if ( $?HOST ) then
	if	( "$HOST" =~ dkinzler* || "$HOST" =~ pcp[0-9]* || \
		  "$HOST" =~ alamo*    || "$HOST" =~ swank*    || \
		  "$HOST" =~ trendy*   || "$HOST" =~ transit* ) then
		setenv LINUX bs
	else if ( "$HOST" =~ ?kinzler* || "$HOST" == 141.211.15.29 ) then
		setenv LINUX del
	else if ( "$HOST" != "" ) then
		if ( "`hosts -l "$HOST"`" =~ *linux* ) setenv LINUX del
	endif
endif

#setenv ERASE ^H
setenv ERASE ^\?
if ( $?LINUX ) then
#	if ( "$LINUX" == del ) setenv ERASE ^\?
	if ( "$LINUX" == bs  ) setenv ERASE ^H
endif
stty erase "$ERASE" kill ^U susp ^Z intr ^C quit ^\\

if ( $TERM =~ xterm* || $TERM == vt220 || $TERM == putty ) then
	if ( ! $?KINDLE ) then
		resize
	endif
endif

mesg y
if ( $TERM !~ xterm* ) (biff y) >& /dev/null

if ( ! $?DISPLAY && $TERM =~ xterm* ) then
	setenv DISPLAY "${REMOTEHOST}:0"
	echo "DISPLAY=$DISPLAY"
endif

if ( $?BASEPATH ) setenv BACKPATH `echo "$BASEPATH" | sed 's/ /:/g'`

# only so tcsh hack for vsh works
#if ( ! $?tcsh && ! $?DT && ! $?GDMSESSION ) then
if ( ! $?DT && ! $?GDMSESSION ) then
	tcsh -f /dev/null && exec tcsh
endif
source ~/.cshrc